Vous êtes l’entier propriétaire des données que vous produisez sur pearltrees. A tout moment, vous pouvez récupérer votre organisation du web dans un format standard qu’est le RDF. Cet opération s’effectue dans les settings de votre compte pearltrees, vous pouvez y télécharger un fichier RDF, le stocker sur votre ordinateur ou le re-publier sur votre site. RDF est un merveilleux format pour partager des données sur le web, et il est donc très facile de le réutiliser pour obtenir des informations sur votre compte.

Dans les examples ci-dessous j’ai décidé d’explorer un peu plus le contenu de mon compte cyno.tv. La toute première étape est de mettre en ligne ses données téléchargées sur pearltrees:
ex: http://nicolas.cynober.fr/pearltrees_export_cyno.tv.rdf

Ensuite il vous suffit d’écrire des requêtes comme pour une base de données classique. Un bon moyen est d’utiliser le language SPARQL. Cela peut être fait en ligne grâce à des outils comme SPARQLer.

Voici quelques requêtes effectuées sur l’export de mon compte cyno.tv:

La liste de toutes mes perles avec leurs URLs

PREFIX pt: <http://www.pearltrees.com/rdf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>

SELECT ?title ?url
FROM <http://nicolas.cynober.fr/pearltrees_export_cyno.tv.rdf>
WHERE {
   ?pearl rdf:type pt:pearl;
          dc:title ?title;
          owl:sameAs ?url;
          pt:parentTree ?tree
}
ORDER BY DESC (?tree)

Résultat, un tableau de 133 urls.

La répartition de mes vidéos entre Youtube, Dailymotion et Vimeo

PREFIX pt: <http://www.pearltrees.com/rdf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT COUNT(?url) COUNT(?url2) COUNT(?url3)
FROM <http://nicolas.cynober.fr/pearltrees_export_cyno.tv.rdf>
WHERE {
   {
      ?pearl rdf:type pt:pearl;
             owl:sameAs ?url.
      FILTER regex(str(?url), "youtube", "i")
   }
   UNION {
      ?pearl2 rdf:type pt:pearl;
              owl:sameAs ?url2.
      FILTER regex(str(?url2), "dailymotion", "i")
   }
   UNION {
      ?pearl3 rdf:type pt:pearl;
              owl:sameAs ?url3.
      FILTER regex(str(?url3), "vimeo", "i")
   }
}

Résultat, youtube: 57, dailymotion: 57, vimeo: 4.

Les perles communes avec la teo.tv
Teo a lui aussi mis en ligne son export RDF. Je peux maintenant comparer sa webTV avec la mienne.

PREFIX pt: <http://www.pearltrees.com/rdf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX data: <http://nicolas.cynober.fr/pearltrees_export_>

SELECT ?cyno_title ?teo_title ?url
FROM NAMED <http://nicolas.cynober.fr/pearltrees_export_cyno.tv.rdf>
FROM NAMED <http://nicolas.cynober.fr/pearltrees_export_teo.tv.rdf>
WHERE {
   GRAPH data:cyno.tv.rdf {
      ?pearl rdf:type pt:pearl;
             dc:title ?cyno_title;
             owl:sameAs ?url.
   }.
   GRAPH data:teo.tv.rdf {
      ?pearl2 rdf:type pt:pearl;
              dc:title ?teo_title;
              owl:sameAs ?url.
   }
}

Résultat, 3 perles en commun.